Sssxh BLOG
0%

腾讯桌面整理图标错乱恢复

发表于 分类于 阅读次数： 57

由于电脑文件太杂，所以使用了 腾讯桌面整理 来对文件进行归类。但是隔段时间就会出现整理好的文件错乱的问题，定位下来是因为显示器分辨率变了导致的，我接了一个外接显示器，主显示器分辨率是 2K，外接显示器分辨率是 1080P，有时候电脑开机后，就会出现桌面图标错乱的清况。之前出现这种清况，都是一个个文件重新排列….

今天又碰到了这个问题，想着能不能找一个办法，一劳永逸的解决这个问题。看到了这篇文章：腾讯桌面整理连接扩展屏幕异常处理。文中作者提到：

经过使用发现其配置文件就是ConFile.dat、DesktopMgr.lg、FencesDataFile.dat这三个文件，所以只需要备份这三个文件即可。

作者给出了一段脚本，如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
@echo off
echo current time is %date%  %time%
:begin
echo OPTIONS:
echo 1.back up
echo 2.refresh
set option=
set /p option=Please choose the option:
echo %option%
FOR /F "delims=" %%k in ('wmic process get executablepath^|findstr DesktopMgr') DO SET RunPath=%%k
echo %RunPath%
FOR /F "delims=" %%k in ('wmic process get name^|findstr DesktopMgr') DO SET Name=%%k
echo %Name%
Set "WMIC_Command=wmic path Win32_VideoController get VideoModeDescription^,CurrentHorizontalResolution^,CurrentVerticalResolution /format:Value"
Set "H=CurrentHorizontalResolution"
Set "V=CurrentVerticalResolution"
Call :GetResolution %H% HorizontalResolution
Call :GetResolution %V% VerticalResolution
::Screen Resolution
echo  Screen Resolution is : %HorizontalResolution% x %VerticalResolution%
SET GenDir="%APPDATA%\Tencent\DeskGo\Backup\%HorizontalResolution% x %VerticalResolution%"
echo %GenDir%
if not exist %GenDir% (
  md "%APPDATA%\Tencent\DeskGo\Backup\%HorizontalResolution% x %VerticalResolution%"
) else (
  echo %GenDir%
)
if "%option%"=="1" (
:: backup Your config files to %APPDATA%\Tencent\DeskGo\Backup\%HorizontalResolution% x %VerticalResolution%
copy  /Y  "%APPDATA%\Tencent\DeskGo\ConFile.dat" "%APPDATA%\Tencent\DeskGo\Backup\%HorizontalResolution% x %VerticalResolution%\ConFile.dat"
copy  /Y  "%APPDATA%\Tencent\DeskGo\DesktopMgr.lg" "%APPDATA%\Tencent\DeskGo\Backup\%HorizontalResolution% x %VerticalResolution%\DesktopMgr.lg"
copy  /Y  "%APPDATA%\Tencent\DeskGo\FencesDataFile.dat" "%APPDATA%\Tencent\DeskGo\Backup\%HorizontalResolution% x %VerticalResolution%\FencesDataFile.dat"
) else (
::kill
taskkill /F /IM %Name%
::Your backup config files eg:**/1920 x 1080
copy  /Y "%APPDATA%\Tencent\DeskGo\Backup\%HorizontalResolution% x %VerticalResolution%" "%APPDATA%\Tencent\DeskGo"
::The DeskGo installed directory
"%RunPath%"
)
goto begin
::****************************************************
:GetResolution 
FOR /F "tokens=2 delims==" %%I IN (
  '%WMIC_Command% ^| find /I "%~1" 2^>^nul'
) DO FOR /F "delims=" %%A IN ("%%I") DO SET "%2=%%A"
Exit /b
::****************************************************

新建一个文件，将上面的内容复制进去，文件后缀修改为 bat，之后执行即可。

每次桌面图标有变更，就执行1，进行备份；如果桌面图标错乱，那么就执行2，恢复到之前备份的版本。

此外还有一种更便捷的处理办法，不需要添加脚本。注意上面的文件夹中，有几个 FencesDataFile_temp_x 文件，这几个文件是程序自动备份的，如果出现桌面图标错乱的清况，根据备份文件的修改时间，选择一个正常时间的文件，将其重命名为 FencesDataFile.dat，之后再重启软件即可。由于整理软件没有任务栏图标，因此先要去任务管理器结束进程，之后再重新启动软件：

参考文章

DeskGo腾讯桌面整理连接扩展屏幕异常处理

腾讯电脑管家桌面整理图标错乱解决方法